{
  description = "VRChat Event Tracker";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    crane = {
      url = "github:ipetkov/crane";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.rust-analyzer-src.follows = "";
    };

    flake-utils.url = "github:numtide/flake-utils";

    advisory-db = {
      url = "github:rustsec/advisory-db";
      flake = false;
    };
  };

  outputs = { self, nixpkgs, crane, fenix, flake-utils, advisory-db, ... }: {
    nixosModules.default = ({ pkgs, ... }: {
      imports = [ ./module.nix ];
      # defined overlays injected by the nixflake
      nixpkgs.overlays = [
        (_self: _super: {
          vrchat-prometheus-adapter = self.packages.${pkgs.system}.vrchat-prometheus-adapter;
        })
      ];
    });
  } //
  flake-utils.lib.eachDefaultSystem (system:
    let
      pkgs = import nixpkgs {
        inherit system;
      };

      inherit (pkgs) lib;

      craneLib = crane.lib.${system};
      src = craneLib.cleanCargoSource (craneLib.path ./.);
      # Common arguments can be set here to avoid repeating them later
      commonArgs = {
        inherit src;
        buildInputs = [
          pkgs.pkg-config
          pkgs.openssl
        ] ++ lib.optionals pkgs.stdenv.isDarwin [
          # Additional darwin specific inputs can be set here
          pkgs.libiconv
        ];
      };

      craneLibLLvmTools = craneLib.overrideToolchain
        (fenix.packages.${system}.complete.withComponents [
          "cargo"
          "llvm-tools"
          "rustc"
        ]);

      # Build *just* the cargo dependencies, so we can reuse
      # all of that work (e.g. via cachix) when running in CI
      cargoArtifacts = craneLib.buildDepsOnly commonArgs;

      # Build the actual crate itself, reusing the dependency
      # artifacts from above.
      
      vrchat-prometheus-adapter = craneLib.buildPackage (commonArgs // {
        inherit cargoArtifacts;
      });

      dockerImage = pkgs.dockerTools.buildImage {
        name = "vrchat-prometheus-exporter";
        copyToRoot = [ vrchat-prometheus-adapter pkgs.cacert ];

        config = {
          Cmd = [ "${vrchat-prometheus-adapter}/bin/vrchat-prometheus-adapter" ];
          ExposedPorts = {
            "6534/tcp" = {};
          };
        };
      };

    in
      {
        checks = {
          inherit vrchat-prometheus-adapter;

          vrchat-prometheus-adapter-clippy = craneLib.cargoClippy (commonArgs // {
            inherit cargoArtifacts;
            cargoClippyExtraArgs = "--all-targets -- --deny warnings";
          });

          vrchat-prometheus-adapter-doc = craneLib.cargoDoc (commonArgs // {
            inherit cargoArtifacts;
          });
          vrchat-prometheus-adapter-fmt = craneLib.cargoFmt {
            inherit src;
          };
          vrchat-prometheus-adapter-audit = craneLib.cargoAudit {
            inherit src advisory-db;
          };
          vrchat-prometheus-adapter-nextest = craneLib.cargoNextest (commonArgs // {
            inherit cargoArtifacts;
            partitions = 1;
            partitionType = "count";
          });
        };

        packages = {
          default = vrchat-prometheus-adapter;
          docker = dockerImage;
          vrchat-prometheus-adapter-llvm-coverage = craneLibLLvmTools.cargoLlvmCov (commonArgs // {
            inherit cargoArtifacts;
          });
        };

        apps.default = flake-utils.lib.mkApp {
          drv = vrchat-prometheus-adapter;
        };

        devShells.default = pkgs.mkShell {
          inputsFrom = builtins.attrValues self.checks.${system};
          nativeBuildInputs = with pkgs; [
            cargo
            rustc
            rust-analyzer
            cargo-flamegraph
            cargo-bloat
          ];
        };
      });
}