udpt/flake.nix

{
  description = "udp torrent tracker";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    crane = {
      url = "github:ipetkov/crane";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.rust-analyzer-src.follows = "";
    };

    flake-utils.url = "github:numtide/flake-utils";

    advisory-db = {
      url = "github:rustsec/advisory-db";
      flake = false;
    };
  };

  outputs = { self, nixpkgs, crane, fenix, flake-utils, advisory-db, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs {
          inherit system;
        };

        inherit (pkgs) lib;

        craneLib = crane.lib.${system};
        src = craneLib.cleanCargoSource (craneLib.path ./.);
        # Common arguments can be set here to avoid repeating them later
        commonArgs = {
          inherit src;
          buildInputs = [
            pkgs.pkg-config
            pkgs.openssl
          ] ++ lib.optionals pkgs.stdenv.isDarwin [
            # Additional darwin specific inputs can be set here
            pkgs.libiconv
          ];
        };

        craneLibLLvmTools = craneLib.overrideToolchain
          (fenix.packages.${system}.complete.withComponents [
            "cargo"
            "llvm-tools"
            "rustc"
          ]);

        # Build *just* the cargo dependencies, so we can reuse
        # all of that work (e.g. via cachix) when running in CI
        cargoArtifacts = craneLib.buildDepsOnly commonArgs;

        # Build the actual crate itself, reusing the dependency
        # artifacts from above.
        
        udpt = craneLib.buildPackage (commonArgs // {
          inherit cargoArtifacts;
        });

        dockerImage = pkgs.dockerTools.buildImage {
          name = "vrchat-prometheus-exporter";
          copyToRoot = [ udpt pkgs.cacert ];

          config = {
            Cmd = [ "${udpt}/bin/udpt" ];
            ExposedPorts = {
              "1212/tcp" = {};
              "1212/udp" = {};
            };
          };
        };

      in
        {
          checks = {
            inherit udpt;

            udpt-clippy = craneLib.cargoClippy (commonArgs // {
              inherit cargoArtifacts;
              cargoClippyExtraArgs = "--all-targets -- --deny warnings";
            });

            udpt-doc = craneLib.cargoDoc (commonArgs // {
              inherit cargoArtifacts;
            });
            udpt-fmt = craneLib.cargoFmt {
              inherit src;
            };
            udpt-audit = craneLib.cargoAudit {
              inherit src advisory-db;
            };
            udpt-nextest = craneLib.cargoNextest (commonArgs // {
              inherit cargoArtifacts;
              partitions = 1;
              partitionType = "count";
            });
          };

          packages = {
            default = udpt;
            docker = dockerImage;
            udpt-llvm-coverage = craneLibLLvmTools.cargoLlvmCov (commonArgs // {
              inherit cargoArtifacts;
            });
          };

          apps.default = flake-utils.lib.mkApp {
            drv = udpt;
          };

          devShells.default = pkgs.mkShell {
            inputsFrom = builtins.attrValues self.checks.${system};
            nativeBuildInputs = with pkgs; [
              cargo
              rustc
              rust-analyzer
              cargo-flamegraph
              cargo-bloat
            ];
          };
        });
}