dref/flake.nix

{
  description = "Docker registry frontend & basic library";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    crane = {
      url = "github:ipetkov/crane";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flake-utils.url = "github:numtide/flake-utils";

    Xess.url = "github:Xe/Xess";
  };

  outputs = { self, nixpkgs, crane, flake-utils, Xess, ... }:
    flake-utils.lib.eachSystem [ "x86_64-linux" "aarch64-linux" ] (system:
      let
        pkgs = import nixpkgs {
          inherit system;
        };

        craneLib = crane.lib.${system};
        dref = craneLib.buildPackage {
          src = craneLib.cleanCargoSource ./.;

          buildInputs = [
            # Add additional build inputs here
            pkgs.openssl
            pkgs.pkg-config
          ] ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
            # Additional darwin specific inputs can be set here
            pkgs.libiconv
          ];
        };

        dockerImage = pkgs.dockerTools.buildImage {
          name = "dref";
          config = {
            Cmd = [ "${dref}/bin/dref" ];
            ExposedPorts = {
              "3000/tcp" = {};
            };
          };
        };
      in
      {
        checks = {
          inherit dref;
        };

        apps.default = flake-utils.lib.mkApp {
          drv = dref;
        };

        packages = rec {
          bin = dref;
          docker = dockerImage;
          default = pkgs.symlinkJoin {
            name = "dref-${bin.version}";
            paths = [ bin ];
          };
        };

        defaultPackage = self.packages.${system}.bin;

        devShells.default = pkgs.mkShell {
          inputsFrom = builtins.attrValues self.checks;

          # Extra inputs can be added here
          nativeBuildInputs = with pkgs; [
            cargo
            rustc
            rust-analyzer
            openssl
            pkg-config
          ];
        };
      });
}